Merge branch 'master' into core-updates

3 files changed, 141 insertions, 4 deletions

diff --git a/guix/build/ant-build-system.scm b/guix/build/ant-build-system.scm
index 27277af34b..6dc19ff2db 100644
--- a/guix/build/ant-build-system.scm
+++ b/guix/build/ant-build-system.scm
@@ -86,6 +86,17 @@ INPUTS."
                          (find-files dir "\\.*jar$")))
                       inputs)) ":"))
 
+(define* (unpack #:key source #:allow-other-keys)
+  "Unpack the jar archive SOURCE.  When SOURCE is not a jar archive fall back
+to the default GNU unpack strategy."
+  (if (string-suffix? ".jar" source)
+      (begin
+        (mkdir "src")
+        (with-directory-excursion "src"
+          (zero? (system* "jar" "-xf" source))))
+      ;; Use GNU unpack strategy for things that aren't jar archives.
+      ((assq-ref gnu:%standard-phases 'unpack) #:source source)))
+
 (define* (configure #:key inputs outputs (jar-name #f)
                     #:allow-other-keys)
   (when jar-name
@@ -151,6 +162,7 @@ repack them.  This is necessary to ensure that archives are reproducible."
 
 (define %standard-phases
   (modify-phases gnu:%standard-phases
+    (replace 'unpack unpack)
     (replace 'configure configure)
     (replace 'build build)
     (replace 'check check)
diff --git a/guix/build/download.scm b/guix/build/download.scm
index fec4cec3e8..7741726c41 100644
--- a/guix/build/download.scm
+++ b/guix/build/download.scm
@@ -426,6 +426,85 @@ port if PORT is a TLS session record port."
 (module-define! (resolve-module '(web client))
                 'shutdown (const #f))
 
+
+;; XXX: Work around <http://bugs.gnu.org/23421>, fixed in Guile commit
+;; 16050431f29d56f80c4a8253506fc851b8441840.  Guile's date validation
+;; procedure rejects dates in which the hour is not padded with a zero but
+;; with whitespace.
+(begin
+  (define-syntax string-match?
+    (lambda (x)
+      (syntax-case x ()
+        ((_ str pat) (string? (syntax->datum #'pat))
+         (let ((p (syntax->datum #'pat)))
+           #`(let ((s str))
+               (and
+                (= (string-length s) #,(string-length p))
+                #,@(let lp ((i 0) (tests '()))
+                     (if (< i (string-length p))
+                         (let ((c (string-ref p i)))
+                           (lp (1+ i)
+                               (case c
+                                 ((#\.)  ; Whatever.
+                                  tests)
+                                 ((#\d)  ; Digit.
+                                  (cons #`(char-numeric? (string-ref s #,i))
+                                        tests))
+                                 ((#\a)  ; Alphabetic.
+                                  (cons #`(char-alphabetic? (string-ref s #,i))
+                                        tests))
+                                 (else   ; Literal.
+                                  (cons #`(eqv? (string-ref s #,i) #,c)
+                                        tests)))))
+                         tests)))))))))
+
+  (define (parse-rfc-822-date str space zone-offset)
+    (let ((parse-non-negative-integer (@@ (web http) parse-non-negative-integer))
+          (parse-month (@@ (web http) parse-month))
+          (bad-header (@@ (web http) bad-header)))
+      ;; We could verify the day of the week but we don't.
+      (cond ((string-match? (substring str 0 space) "aaa, dd aaa dddd dd:dd:dd")
+             (let ((date (parse-non-negative-integer str 5 7))
+                   (month (parse-month str 8 11))
+                   (year (parse-non-negative-integer str 12 16))
+                   (hour (parse-non-negative-integer str 17 19))
+                   (minute (parse-non-negative-integer str 20 22))
+                   (second (parse-non-negative-integer str 23 25)))
+               (make-date 0 second minute hour date month year zone-offset)))
+            ((string-match? (substring str 0 space) "aaa, d aaa dddd dd:dd:dd")
+             (let ((date (parse-non-negative-integer str 5 6))
+                   (month (parse-month str 7 10))
+                   (year (parse-non-negative-integer str 11 15))
+                   (hour (parse-non-negative-integer str 16 18))
+                   (minute (parse-non-negative-integer str 19 21))
+                   (second (parse-non-negative-integer str 22 24)))
+               (make-date 0 second minute hour date month year zone-offset)))
+
+            ;; The next two clauses match dates that have a space instead of
+            ;; a leading zero for hours, like " 8:49:37".
+            ((string-match? (substring str 0 space) "aaa, dd aaa dddd  d:dd:dd")
+             (let ((date (parse-non-negative-integer str 5 7))
+                   (month (parse-month str 8 11))
+                   (year (parse-non-negative-integer str 12 16))
+                   (hour (parse-non-negative-integer str 18 19))
+                   (minute (parse-non-negative-integer str 20 22))
+                   (second (parse-non-negative-integer str 23 25)))
+               (make-date 0 second minute hour date month year zone-offset)))
+            ((string-match? (substring str 0 space) "aaa, d aaa dddd  d:dd:dd")
+             (let ((date (parse-non-negative-integer str 5 6))
+                   (month (parse-month str 7 10))
+                   (year (parse-non-negative-integer str 11 15))
+                   (hour (parse-non-negative-integer str 17 18))
+                   (minute (parse-non-negative-integer str 19 21))
+                   (second (parse-non-negative-integer str 22 24)))
+               (make-date 0 second minute hour date month year zone-offset)))
+
+            (else
+             (bad-header 'date str)        ; prevent tail call
+             #f))))
+  (module-set! (resolve-module '(web http))
+               'parse-rfc-822-date parse-rfc-822-date))
+
 ;; XXX: Work around <http://bugs.gnu.org/19840>, present in Guile
 ;; up to 2.0.11.
 (unless (or (> (string->number (major-version)) 2)
@@ -605,10 +684,22 @@ Return a list of URIs."
     (else
      (list uri))))
 
-(define* (url-fetch url file #:key (mirrors '()))
+(define* (url-fetch url file
+                    #:key
+                    (mirrors '()) (content-addressed-mirrors '())
+                    (hashes '()))
   "Fetch FILE from URL; URL may be either a single string, or a list of
 string denoting alternate URLs for FILE.  Return #f on failure, and FILE
-on success."
+on success.
+
+When MIRRORS is defined, it must be an alist of mirrors; it is used to resolve
+'mirror://' URIs.
+
+HASHES must be a list of algorithm/hash pairs, where each algorithm is a
+symbol such as 'sha256 and each hash is a bytevector.
+CONTENT-ADDRESSED-MIRRORS must be a list of procedures that, given a hash
+algorithm and a hash, return a URL where the specified data can be retrieved
+or #f."
   (define uri
     (append-map (cut maybe-expand-mirrors <> mirrors)
                 (match url
@@ -628,13 +719,21 @@ on success."
                uri)
        #f)))
 
+  (define content-addressed-urls
+    (append-map (lambda (make-url)
+                  (filter-map (match-lambda
+                                ((hash-algo . hash)
+                                 (make-url hash-algo hash)))
+                              hashes))
+                content-addressed-mirrors))
+
   ;; Make this unbuffered so 'progress-proc' works as expected.  _IOLBF means
   ;; '\n', not '\r', so it's not appropriate here.
   (setvbuf (current-output-port) _IONBF)
 
   (setvbuf (current-error-port) _IOLBF)
 
-  (let try ((uri uri))
+  (let try ((uri (append uri content-addressed-urls)))
     (match uri
       ((uri tail ...)
        (or (fetch uri file)
diff --git a/guix/build/graft.scm b/guix/build/graft.scm
index b216e6c0d7..b61982dd64 100644
--- a/guix/build/graft.scm
+++ b/guix/build/graft.scm
@@ -83,6 +83,28 @@ writing the result to OUTPUT."
                           (put-u8 output (char->integer char))
                           result)))))
 
+(define (rename-matching-files directory mapping)
+  "Apply MAPPING to the names of all the files in DIRECTORY, where MAPPING is
+a list of store file name pairs."
+  (let* ((mapping (map (match-lambda
+                        ((source . target)
+                         (cons (basename source) (basename target))))
+                       mapping))
+         (matches (find-files directory
+                              (lambda (file stat)
+                                (assoc-ref mapping (basename file)))
+                              #:directories? #t)))
+
+    ;; XXX: This is not quite correct: if MAPPING contains "foo", and
+    ;; DIRECTORY contains "bar/foo/foo", we first rename "bar/foo" and then
+    ;; "bar/foo/foo" no longer exists so we fail.  Oh well, surely that's good
+    ;; enough!
+    (for-each (lambda (file)
+                (let ((target (assoc-ref mapping (basename file))))
+                  (rename-file file
+                               (string-append (dirname file) "/" target))))
+              matches)))
+
 (define* (rewrite-directory directory output mapping
                             #:optional (store (%store-directory)))
   "Copy DIRECTORY to OUTPUT, replacing strings according to MAPPING, a list of
@@ -115,6 +137,8 @@ file name pairs."
                    (replace-store-references input output mapping
                                              store)
                    (chmod output (stat:perms stat))))))))
+        ((directory)
+         (mkdir-p dest))
         (else
          (error "unsupported file type" stat)))))
 
@@ -124,6 +148,8 @@ file name pairs."
   (umask #o022)
 
   (n-par-for-each (parallel-job-count)
-                  rewrite-leaf (find-files directory)))
+                  rewrite-leaf (find-files directory (const #t)
+                                           #:directories? #t))
+  (rename-matching-files output mapping))
 
 ;;; graft.scm ends here